@echo off
chcp 65001 >nul
setlocal EnableExtensions
rem ============================================================================
rem  Katern Setup for Windows (katern.pages.dev)
rem  What it does, and nothing more:
rem   1. downloads https://katern.pages.dev/download/Katern.zip (with curl.exe from Windows)
rem   2. unpacks it into your Downloads folder, in the folder Katern (with tar.exe from Windows)
rem   3. puts that folder's path on the clipboard
rem   4. opens Chrome on the install page, which shows the last 3 clicks
rem  It installs nothing in Windows, changes no settings and needs no administrator.
rem  Chrome itself must still load the folder: only you can do that, on chrome://extensions.
rem ============================================================================

rem ---- Language of the messages: from Windows (nl, fr, de, es, it, else English).
set "LOC=en"
for /f "tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v LocaleName 2^>nul ^| find "LocaleName"') do set "LOC=%%a"
set "L=en"
if /i "%LOC:~0,2%"=="nl" set "L=nl"
if /i "%LOC:~0,2%"=="fr" set "L=fr"
if /i "%LOC:~0,2%"=="de" set "L=de"
if /i "%LOC:~0,2%"=="es" set "L=es"
if /i "%LOC:~0,2%"=="it" set "L=it"
goto taal_%L%

:taal_nl
set "T_TITLE=Katern installeren"
set "T_DL=Katern downloaden..."
set "T_ERR_DL=Downloaden lukte niet. Kijk of je internet hebt en probeer opnieuw."
set "T_UNZIP=Uitpakken naar"
set "T_ERR_ZIP=Uitpakken lukte niet."
set "T_OTHER=Er staat al een andere map Katern. Katern komt daarom in"
set "T_OK=Klaar. Katern staat in deze map:"
set "T_CLIP=Die map staat ook op je klembord."
set "T_NEXT=Nu nog 3 stappen in Chrome (de uitleg staat open in Chrome):"
set "T_S1=1. Typ chrome://extensions in de adresbalk en druk Enter."
set "T_S2=2. Zet rechtsboven Ontwikkelaarsmodus aan."
set "T_S3=3. Klik Uitgepakte extensie laden, klik onderaan in het vak Map, druk Ctrl+V en klik Map selecteren."
set "T_UPD=Had je Katern al uit deze map? Klik dan in chrome://extensions op het ronde pijltje bij Katern."
set "T_NOCHROME=Google Chrome is niet gevonden. Katern werkt alleen in Chrome."
set "T_END=Druk op een toets om dit venster te sluiten."
goto start
:taal_fr
set "T_TITLE=Installer Katern"
set "T_DL=Téléchargement de Katern..."
set "T_ERR_DL=Le téléchargement n'a pas marché. Vérifie ta connexion et réessaie."
set "T_UNZIP=Décompression dans"
set "T_ERR_ZIP=La décompression n'a pas marché."
set "T_OTHER=Il y a déjà un autre dossier Katern. Katern va donc dans"
set "T_OK=C'est prêt. Katern est dans ce dossier :"
set "T_CLIP=Ce dossier est aussi copié dans ton presse-papiers."
set "T_NEXT=Encore 3 étapes dans Chrome (l'explication est ouverte dans Chrome) :"
set "T_S1=1. Tape chrome://extensions dans la barre d'adresse et appuie sur Entrée."
set "T_S2=2. Active Mode développeur, en haut à droite."
set "T_S3=3. Clique sur Charger l'extension non empaquetée, clique dans la case Dossier en bas, appuie sur Ctrl+V et clique sur Sélectionner un dossier."
set "T_UPD=Katern venait déjà de ce dossier ? Clique alors sur la flèche ronde de Katern dans chrome://extensions."
set "T_NOCHROME=Google Chrome est introuvable. Katern ne marche que dans Chrome."
set "T_END=Appuie sur une touche pour fermer cette fenêtre."
goto start
:taal_de
set "T_TITLE=Katern installieren"
set "T_DL=Katern wird heruntergeladen..."
set "T_ERR_DL=Das Herunterladen hat nicht geklappt. Prüf dein Internet und versuch es nochmal."
set "T_UNZIP=Entpacken nach"
set "T_ERR_ZIP=Das Entpacken hat nicht geklappt."
set "T_OTHER=Es gibt schon einen anderen Ordner Katern. Katern kommt deshalb nach"
set "T_OK=Fertig. Katern liegt in diesem Ordner:"
set "T_CLIP=Der Ordner ist auch in deiner Zwischenablage."
set "T_NEXT=Jetzt noch 3 Schritte in Chrome (die Anleitung ist in Chrome offen):"
set "T_S1=1. Tipp chrome://extensions in die Adressleiste und drück Enter."
set "T_S2=2. Schalte oben rechts den Entwicklermodus ein."
set "T_S3=3. Klick auf Entpackte Erweiterung laden, klick unten in das Feld Ordner, drück Strg+V und klick auf Ordner auswählen."
set "T_UPD=Kam Katern schon aus diesem Ordner? Dann klick in chrome://extensions auf den runden Pfeil bei Katern."
set "T_NOCHROME=Google Chrome wurde nicht gefunden. Katern funktioniert nur in Chrome."
set "T_END=Drück eine Taste, um dieses Fenster zu schließen."
goto start
:taal_es
set "T_TITLE=Instalar Katern"
set "T_DL=Descargando Katern..."
set "T_ERR_DL=La descarga no ha funcionado. Revisa tu conexión e inténtalo otra vez."
set "T_UNZIP=Descomprimiendo en"
set "T_ERR_ZIP=No se ha podido descomprimir."
set "T_OTHER=Ya hay otra carpeta Katern. Por eso Katern va a"
set "T_OK=Listo. Katern está en esta carpeta:"
set "T_CLIP=La carpeta también está en tu portapapeles."
set "T_NEXT=Faltan 3 pasos en Chrome (la explicación está abierta en Chrome):"
set "T_S1=1. Escribe chrome://extensions en la barra de direcciones y pulsa Intro."
set "T_S2=2. Activa Modo Desarrollador, arriba a la derecha."
set "T_S3=3. Haz clic en Cargar descomprimida, haz clic abajo en la casilla Carpeta, pulsa Ctrl+V y haz clic en Seleccionar carpeta."
set "T_UPD=¿Katern ya venía de esta carpeta? Entonces pulsa la flecha redonda de Katern en chrome://extensions."
set "T_NOCHROME=No se encuentra Google Chrome. Katern solo funciona en Chrome."
set "T_END=Pulsa una tecla para cerrar esta ventana."
goto start
:taal_it
set "T_TITLE=Installare Katern"
set "T_DL=Download di Katern..."
set "T_ERR_DL=Il download non è riuscito. Controlla la connessione e riprova."
set "T_UNZIP=Estrazione in"
set "T_ERR_ZIP=L'estrazione non è riuscita."
set "T_OTHER=C'è già un'altra cartella Katern. Katern va quindi in"
set "T_OK=Fatto. Katern è in questa cartella:"
set "T_CLIP=La cartella è anche negli appunti."
set "T_NEXT=Mancano 3 passi in Chrome (la spiegazione è aperta in Chrome):"
set "T_S1=1. Scrivi chrome://extensions nella barra degli indirizzi e premi Invio."
set "T_S2=2. Attiva Modalità sviluppatore, in alto a destra."
set "T_S3=3. Clicca Carica estensione non pacchettizzata, clicca in basso nella casella Cartella, premi Ctrl+V e clicca Seleziona cartella."
set "T_UPD=Katern veniva già da questa cartella? Allora clicca la freccia rotonda di Katern in chrome://extensions."
set "T_NOCHROME=Google Chrome non trovato. Katern funziona solo in Chrome."
set "T_END=Premi un tasto per chiudere questa finestra."
goto start
:taal_en
set "T_TITLE=Install Katern"
set "T_DL=Downloading Katern..."
set "T_ERR_DL=The download did not work. Check your internet and try again."
set "T_UNZIP=Unpacking into"
set "T_ERR_ZIP=Unpacking did not work."
set "T_OTHER=There is already another folder Katern. So Katern goes into"
set "T_OK=Done. Katern is in this folder:"
set "T_CLIP=That folder is also on your clipboard."
set "T_NEXT=Now 3 more steps in Chrome (the explanation is open in Chrome):"
set "T_S1=1. Type chrome://extensions in the address bar and press Enter."
set "T_S2=2. Turn on Developer mode, at the top right."
set "T_S3=3. Click Load unpacked, click the Folder box at the bottom, press Ctrl+V and click Select Folder."
set "T_UPD=Did Katern already come from this folder? Then click the round arrow next to Katern in chrome://extensions."
set "T_NOCHROME=Google Chrome was not found. Katern only works in Chrome."
set "T_END=Press a key to close this window."
goto start

:start
title %T_TITLE%
set "PAGE=https://katern.pages.dev/%L%/installeer/#na-setup"
if "%L%"=="en" set "PAGE=https://katern.pages.dev/installeer/#na-setup"

rem ---- Chrome: from the App Paths entry that Chrome's installer writes (per machine or per user).
rem (The name of the default value differs per language, e.g. "(par défaut)", so take what comes after REG_SZ.)
call :chromepad "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe"
if not defined CHROME call :chromepad "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe"
if not defined CHROME (
  echo.
  echo %T_NOCHROME%
  start "" "%PAGE%"
  goto einde
)

rem ---- The Downloads folder (it can be moved, so ask Windows), then the folder Katern in it. The update button in
rem      Katern can write there; it could not in AppData (Chrome blocks that for websites and extensions).
set "DL="
for /f "tokens=2,*" %%a in ('reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders" /v "{374DE290-123F-4565-9164-39C4925E467B}" 2^>nul ^| find "REG_"') do call set "DL=%%b"
if not defined DL set "DL=%USERPROFILE%\Downloads"
if not exist "%DL%\" set "DL=%USERPROFILE%\Downloads"
rem Only for Katern's own tests: another folder, zip address, and no Chrome/clipboard/pause.
if defined KATERN_SETUP_TEST set "DL=%KATERN_SETUP_TEST%"
set "DEST=%DL%\Katern"
rem A folder Katern that is not Katern (no manifest.json, or another extension): never mix files, use Katern-Chrome.
if exist "%DEST%\" (
  if not exist "%DEST%\manifest.json" (
    set "DEST=%DL%\Katern-Chrome"
  ) else (
    find /i "katern" "%DEST%\manifest.json" >nul 2>nul || set "DEST=%DL%\Katern-Chrome"
  )
)

echo.
echo  %T_TITLE%
echo  ------------------------------
echo  %T_DL%
set "ZIPURL=https://katern.pages.dev/download/Katern.zip"
if defined KATERN_SETUP_TEST if defined KATERN_SETUP_ZIPURL set "ZIPURL=%KATERN_SETUP_ZIPURL%"
set "ZIP=%TEMP%\Katern-Setup-%RANDOM%%RANDOM%.zip"
curl.exe --fail --location --silent --show-error --retry 2 --output "%ZIP%" "%ZIPURL%"
if errorlevel 1 (
  echo.
  echo  %T_ERR_DL%
  del "%ZIP%" >nul 2>nul
  goto einde
)

echo  %T_UNZIP% %DEST%
if not exist "%DEST%\" mkdir "%DEST%" >nul 2>nul
tar.exe -xf "%ZIP%" -C "%DEST%"
set "TARERR=%errorlevel%"
del "%ZIP%" >nul 2>nul
if not "%TARERR%"=="0" goto zipfout
if not exist "%DEST%\manifest.json" goto zipfout

rem ---- The folder on the clipboard (Unicode-safe, also for names like Jérôme).
if defined KATERN_SETUP_TEST goto klaar
set "KATERN_DEST=%DEST%"
powershell.exe -NoProfile -NonInteractive -Command "Set-Clipboard -Value $env:KATERN_DEST" >nul 2>nul || (<nul set /p "=%DEST%"| clip)

rem ---- Chrome opens the install page at the last 3 steps.
start "" "%CHROME%" "%PAGE%"

:klaar

echo.
echo  %T_OK%
echo     %DEST%
echo  %T_CLIP%
echo.
echo  %T_NEXT%
echo     %T_S1%
echo     %T_S2%
echo     %T_S3%
echo.
echo  %T_UPD%
goto einde

:zipfout
echo.
echo  %T_ERR_ZIP%

:einde
echo.
echo  %T_END%
if defined KATERN_SETUP_TEST goto :eof
pause >nul
endlocal
exit /b

:chromepad
set "CHROME="
for /f "delims=" %%l in ('reg query %1 /ve 2^>nul ^| find "REG_SZ"') do set "CHROME=%%l"
if not defined CHROME goto :eof
set "CHROME=%CHROME:*REG_SZ=%"
for /f "tokens=*" %%c in ("%CHROME%") do set "CHROME=%%c"
if not exist "%CHROME%" set "CHROME="
goto :eof
